added profiles and readmes

misc/profiles2/fastbike.brf

@@ -0,0 +1,167 @@
+#
+# A fastbike could be a racing bike or a speed pedelec.
+# But also at night or in rainy whether you might want
+# to fallback to this one.
+#
+# Structure is similar to trekking.brf, see this for documenation.
+# 
+
+---context:global   # following code refers to global config
+
+# Use the following switches to change behaviour
+# (1=yes, 0=no):
+
+assign   consider_elevation   1   # set to 0 to ignore elevation in routing
+assign   allow_steps          1   # set to 0 to disallow steps
+assign   allow_ferries        1   # set to 0 to disallow ferries
+assign   ignore_cycleroutes   0   # set to 1 for better elevation results
+assign   stick_to_cycleroutes 0   # set to 1 to just follow cycleroutes
+assign   avoid_unsafe         0   # set to 1 to avoid standard highways
+
+assign   validForBikes        1
+
+# the elevation parameters
+
+assign downhillcost switch consider_elevation 60 0
+assign downhillcutoff 1.5
+assign uphillcost 0
+assign uphillcutoff 1.5
+
+---context:way   # following code refers to way-tags
+
+
+
+assign ispaved or surface=paved or surface=asphalt or surface=concrete surface=paving_stones
+assign isunpaved not or surface= or ispaved or surface=fine_gravel surface=cobblestone
+
+assign turncost 90
+
+assign initialcost switch highway=ferry 10000 0
+
+#
+# implicit access here just from the motorroad tag
+# (implicit access rules from highway tag handled elsewhere)
+#
+assign defaultaccess
+       switch access=
+              not motorroad=yes
+              switch or access=private access=no
+                     0
+                     1
+
+#
+# calculate logical bike access
+#
+assign bikeaccess
+       or longdistancecycleway=yes
+          switch bicycle=
+                 switch vehicle=
+                        defaultaccess
+                        switch or vehicle=private vehicle=no
+                               0
+                               1
+                 not or bicycle=private or bicycle=no bicycle=dismount
+
+#
+# calculate logical foot access
+#
+assign footaccess
+       or bikeaccess
+          or bicycle=dismount
+             switch foot=
+                    defaultaccess
+                    not or foot=private foot=no
+
+#
+# if not bike-, but foot-acess, just a moderate penalty,
+# otherwise access is forbidden
+#
+assign accesspenalty
+       switch bikeaccess
+              0
+              switch footaccess
+                     6
+                     100000
+
+#
+# handle one-ways. On primary roads, wrong-oneways should
+# be close to forbidden, while on other ways we just add
+# 4 to the costfactor (making it at least 5 - you are allowed
+# to push your bike)
+#
+assign oneway
+       switch oneway=
+              junction=roundabout
+              or oneway=yes or oneway=true oneway=1
+assign onewaypenalty
+       switch switch reversedirection=yes oneway oneway=-1
+        switch or cycleway=opposite or cycleway=opposite_lane cycleway=opposite_track 0
+        switch or highway=primary highway=primary_link 50
+        switch or highway=secondary highway=secondary_link 30
+        switch or highway=tertiary highway=tertiary_link 20
+        6.0
+       0.0
+
+assign costfactor
+
+  add max onewaypenalty accesspenalty
+
+  switch or highway=motorway highway=motorway_link    100000
+  switch    highway=proposed                          100000
+  switch or highway=trunk highway=trunk_link          10
+  switch or highway=primary highway=primary_link      1.2
+  switch or highway=secondary highway=secondary_link  1.1
+  switch or highway=tertiary highway=tertiary_link    1.0
+  switch    highway=unclassified                      1.1
+  switch    highway=pedestrian                        10
+  switch    highway=steps                             1000
+  switch    highway=ferry                             5.67
+  switch    highway=bridleway                         5
+  switch    highway=cycleway                          1.3
+  switch or highway=residential highway=living_street switch isunpaved 10 1.2
+  switch    highway=service                           switch isunpaved 10 1.2
+  switch or highway=track or highway=road or highway=path highway=footway
+   switch tracktype=grade1 switch isunpaved 3 1.2
+   switch tracktype=grade2 switch isunpaved 10 3
+   switch tracktype=grade3 10.0
+   switch tracktype=grade4 20.0
+   switch tracktype=grade5 30.0
+   switch bicycle=designated 2.0
+   switch ispaved 2.0 100.0
+   10.0
+
+---context:node  # following code refers to node tags
+
+assign defaultaccess
+       switch access=
+              1 # add default barrier restrictions here!
+              switch or access=private access=no
+                     0
+                     1
+
+assign bikeaccess
+       or or longdistancecycleway=yes lcn=yes
+          switch bicycle=
+                 switch vehicle=
+                        defaultaccess
+                        switch or vehicle=private vehicle=no
+                               0
+                               1
+                 switch or bicycle=private or bicycle=no bicycle=dismount
+                        0
+                        1
+
+assign footaccess
+       or bicycle=dismount
+          switch foot=
+                 defaultaccess
+                 switch or foot=private foot=no
+                        0
+                        1
+
+assign initialcost
+       switch bikeaccess
+              0 
+              switch footaccess
+                     300
+                     1000000